{ config, lib, pkgs, ... }:

let
  cfg = config.ashe.network;
in {
  networking.firewall.allowedTCPPorts = cfg.openPorts;

  networking.interfaces.${cfg.interface}.ipv4.addresses = [ {
    address = cfg.address;
    prefixLength = cfg.prefix;
  } ];

  networking.defaultGateway = cfg.gateway;
  networking.nameservers = cfg.nameservers;

  networking.wireless.enable = cfg.wireless;
  networking.networkmanager.enable = cfg.networkManager;
  
  services.tailscale.enable = cfg.tailscale.enable;

  systemd.services.tailscale-autoconnect = lib.mkIf cfg.tailscale.enable {
    description = "Automatic connection to Tailscale";

    # make sure tailscale is running before trying to connect to tailscale
    after = [ "network-pre.target" "tailscale.service" ];
    wants = [ "network-pre.target" "tailscale.service" ];
    wantedBy = [ "multi-user.target" ];

    # set this service as a oneshot job
    serviceConfig.Type = "oneshot";

    # have the job run this shell script
    script = with pkgs; ''
      # wait for tailscaled to settle
      sleep 2

      # check if we are already authenticated to tailscale
      status="$(${tailscale}/bin/tailscale status -json | ${jq}/bin/jq -r .BackendState)"
      if [ $status = "Running" ]; then # if so, then do nothing
        exit 0
      fi

      # otherwise authenticate with tailscale
      ${tailscale}/bin/tailscale up -authkey ${cfg.tailscale.key}
    '';
  };
}